ClearAll["Global`*"]
(*Jednotná velikost obrázků*)
imgSize=400;
(*Obecná funkce pro 2D animaci křivky*)
animate2D[f_,{t_,tmin_,tmax_},plotRange_]:=
Animate[
ParametricPlot[
f[t],{t,tmin,s},PlotStyle->Directive[RGBColor[0,0.64,0.95],Thick],PlotRange->plotRange,Axes->True,AxesLabel->{"x","y"},Epilog->{Red,PointSize[Large],Point[f[s]]}
],
{s,tmin+10^(-12),tmax},AnimationRunning->False,AnimationRepetitions->1,AnimationRate->.2
]
(*Obecná funkce pro 3D animaci křivky*)
animate3D[f_,{t_,tmin_,tmax_},plotRange_]:=
Animate[
Show[
ParametricPlot3D[
f[t],{t,tmin,s},PlotStyle->Directive[RGBColor[0,0.64,0.95],Thick],PlotRange->plotRange,Axes->True,AxesLabel->{"x","y","z"},Boxed->True,BoxRatios->{1,1,1}
],
Graphics3D[
{Red,AbsolutePointSize[8],Point[f[s]]}
]
],
{s,tmin+10^(-12),tmax},AnimationRunning->False,AnimationRepetitions->1,AnimationRate->.2
]
(*Konkrétní vektorové funkce*)
f[t_]:={t,t^2};
g[t_]:={Cos[3 t],Sin[5 t]};
h[t_]:={3.5 Cos[t]-1.5 Cos[7 t],3.5 Sin[t]-1.5 Sin[7 t]};
w[t_]:={Cos[t],Sin[t],t};
(*Seznam animací*)
plots={animate2D[f,{t,-1,1},{{-1.1,1.1},{-1.1,1.1}}],animate2D[g,{t,0,2 Pi},{{-1.1,1.1},{-1.1,1.1}}],animate2D[h,{t,0,2 Pi},{{-5,5},{-5,5}}],animate3D[w,{t,0,8Pi},{{-1.5,1.5},{-1.5,1.5},{0,8Pi}}]};

(*Výběr animace*)
plots[[4]]